teamcity-gitea-test-task/build.gradle.kts

plugins {
    kotlin("jvm") version "1.9.21"
    id("org.jmailen.kotlinter") version "4.1.0"
    id("org.jetbrains.dokka") version "1.9.10"
    `maven-publish`
}

group = "net.koval.teamcity-gitea-test-task"
version = System.getenv("TINYVM_VERSION")

repositories {
    mavenCentral()
}

dependencies {
    testImplementation(kotlin("test"))
}

tasks.test {
    useJUnitPlatform()
}

kotlin {
    jvmToolchain(17)
}

val dokkaHtml by tasks.getting(org.jetbrains.dokka.gradle.DokkaTask::class)
val javadocJar: TaskProvider<Jar> by tasks.registering(Jar::class) {
    dependsOn(dokkaHtml)
    archiveClassifier.set("javadoc")
    from(dokkaHtml.outputDirectory)
}

publishing {
    publications.register<MavenPublication>("gpr") {
        artifactId = "tinyvm"
        from(components["java"])
        artifact(javadocJar)
        pom {
            name.set("TeamCity support for Gitea - Test Task - tiny version manager")
            description.set("This is a small project to implement a subset of git's functionality in Kotlin and was " +
                "created using the instructions below as part of my application to the JetBrains internship project " +
                "\"TeamCity support for Gitea\".")
            url.set("https://git.koval.net/cyclane/teamcity-gitea-test-task")
            developers {
                developer {
                    id.set("cyclane")
                    name.set("Gleb Koval")
                    email.set("gleb@koval.net")
                }
            }
            scm {
                url.set("https://git.koval.net/cyclane/teamcity-gitea-test-task")
            }
        }
    }

    repositories {
        maven {
            name = "Gitea"
            url = uri("https://git.koval.net/api/packages/cyclane/maven")
            credentials {
                username = System.getenv("GITEA_USERNAME")
                password = System.getenv("GITEA_TOKEN")
            }
        }
    }
}