plugins {
    kotlin("jvm") version "1.9.21"
    id("org.jmailen.kotlinter") version "4.1.0"
    id("org.jetbrains.dokka") version "1.9.10"
    `maven-publish`
}

group = "net.koval.teamcity-build-step-extension-test-task"
version = "0.0.0"

repositories {
    mavenCentral()
}

dependencies {
    testImplementation(kotlin("test"))
}

tasks.test {
    useJUnitPlatform()
}

kotlin {
    jvmToolchain(11)
}

val dokkaHtml by tasks.getting(org.jetbrains.dokka.gradle.DokkaTask::class)
val javadocJar: TaskProvider<Jar> by tasks.registering(Jar::class) {
    dependsOn(dokkaHtml)
    archiveClassifier.set("javadoc")
    from(dokkaHtml.outputDirectory)
}

publishing {
    publications.register<MavenPublication>("gpr") {
        artifactId = "filesystem"
        from(components["java"])
        artifact(javadocJar)
        pom {
            name.set("TeamCity Kotlin Script build step extension library - Test Task - test filesystem")
            description.set("This is a small project to make a very basic filesystem library in Kotlin and was" +
                "created using the instructions below as part of my application to the JetBrains internship project" +
                "\"TeamCity Kotlin Script build step extension library\".")
            url.set("https://git.koval.net/cyclane/teamcity-build-step-extension-test-task")
            developers {
                developer {
                    id.set("cyclane")
                    name.set("Gleb Koval")
                    email.set("gleb@koval.net")
                }
            }
            scm {
                url.set("https://git.koval.net/cyclane/teamcity-build-step-extension-test-task")
            }
        }
    }

    repositories {
        maven {
            name = "Gitea"
            url = uri("https://git.koval.net/api/packages/cyclane/maven")
            credentials {
                username = System.getenv("GITEA_USERNAME")
                password = System.getenv("GITEA_TOKEN")
            }
        }
    }
}